Ansys en una Cáscara de Nuez: Viga en Voladizo

Hallaremos el diagrama de momentos flectores, el de cortantes y la flecha máxima de una viga en voladizo sometida a una carga en punta.

A diferencia del tutorial anterior en el que resolvimos la viga biapoyada usando exculsivamente Ansys, en esta ocasión usaremos también la extensión de Ansys para ingeniería civil: CivilFEM.

Datos del problema

Sección: IPE 80.
Material: Acero EA A37.
Longitud: 3 m.
Carga puntual: 1000 N.

Comandos APDL

! Comenzamos de cero
FINISH
~CFCLEAR,,1

/title, Viga en Voladizo

! Setup CivilFEM: Unidades
~units,SI ! Sistema internacional

/prep7
! Preprocesador CivilFEM
! ----------------------------------------------------------------------
! Material
~cfmp,1,lib,steel,EA,A37
! Listado de propiedades del material que hemos definido
~cfmplst,1,1,1,1,1,1,0,1,0
! Tipo de elemento
et,1,beam3
! Sección
~sseclib,1,1,01,1, IPE 80
~bmshpro,1,beam,1,1,,,3,,0
! Preprocesador Ansys
!-----------------------------------------------------------------------
! Geometría
k,1,0,0,0
k,2,3,0,0
l,1,2
! Tamaño de elemento
lesize,all,0.5
! Mallamos
lmesh,all
/solu
! Solución Ansys
! ----------------------------------------------------------------------
! CC
d,1,all ! empotramiento
! Carga puntual
FK,2,FY,-1000
! Resolver
solve
/post1
! Posprocesador CivilFEM
! ----------------------------------------------------------------------
! Leemos los resultados
~cfset,,1,1
! Momento flector
! El último parámetro es un factor de escala. Cuando es negativo
! impplica que los valores positivos se dibujen en la parte inferior
! de la barra.
~pllsfor,m,z,-3
! Cortante
~pllsfor,f,y,-1
! Lista de fuerzas y momentos
~prfor, both,fy,mz
! Comando Ansys para graficar la viga deformada y sin deformar.
pldisp,2
Resultados

Diagrama de momentos flectores.

Diagrama de cortantes.

Listado de fuerzas y momentos.

Viga deformada y flecha máxima.

Índice